package User::grent 1.05;
use v5.38;
our ($gr_name, $gr_gid, $gr_passwd, @gr_members);
use Exporter 'import';
our @EXPORT = qw(getgrent getgrgid getgrnam getgr);
our @EXPORT_OK = qw($gr_name $gr_gid $gr_passwd @gr_members);
our %EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
use Class::Struct qw(struct);
struct 'User::grent' => [
name => '$',
passwd => '$',
gid => '$',
members => '@',
];
sub populate {
return unless @_;
my $gob = new();
($gr_name, $gr_passwd, $gr_gid) = @$gob[0,1,2] = @_[0,1,2];
@gr_members = @{$gob->[3]} = split ' ', $_[3];
return $gob;
}
sub getgrent :prototype( ) { populate(CORE::getgrent()) }
sub getgrnam :prototype($) { populate(CORE::getgrnam(shift)) }
sub getgrgid :prototype($) { populate(CORE::getgrgid(shift)) }
sub getgr :prototype($) { ($_[0] =~ /^\d+/) ? &getgrgid : &getgrnam }
__END__
=head1 NAME
User::grent - by-name interface to Perl's built-in getgr*() functions
=head1 SYNOPSIS
use User::grent;
my $gr = getgrgid(0) or die "No group zero";
if ( $gr->name eq 'wheel' && @{$gr->members} > 1 ) {
print "gid zero name wheel, with other members";
}
use User::grent qw(:FIELDS);
getgrgid(0) or die "No group zero";
if ( $gr_name eq 'wheel' && @gr_members > 1 ) {
print "gid zero name wheel, with other members";
}
my $gr = getgr($whoever);
=head1 DESCRIPTION
This module's default exports override the core getgrent(), getgrgid(),
and getgrnam() functions, replacing them with versions that return
"User::grent" objects. This object has methods that return the similarly
named structure field name from the C's passwd structure from F